Помогите с Delphi? SpinEdit1 и SpinEdit2

Если задать 0 и 5, то создастся не пять, а шесть файлов.
"цикл спинедитов организовать и показать им что текстовые файлы надо создать в каталоге из edit1" можно, например, так:

unit N98366375;

interface

uses
    Windows, SysUtils, Classes, Forms,
    StdCtrls, Spin, Controls;

type
    TForm1 = class(TForm)
        SpinEdit1: TSpinEdit;
        SpinEdit2: TSpinEdit;
        Edit1: TEdit;
        Button1: TButton;
        procedure Button1Click(Sender: TObject);
    end;

var
    Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
    i: integer;
    FileHandle: Integer;
    Path, FileName: string;
    Mess: TStringList;
begin
    Mess := TStringList.Create;
    Path := ExcludeTrailingPathDelimiter(Edit1.Text);
    if not DirectoryExists(Path) then
        if not ForceDirectories(Path) then
        begin
            MessageBox(0, PChar('Невозможно создать папку ' + Path), 'Ошибка', MB_ICONERROR);
            exit
        end;
    Path := IncludeTrailingPathDelimiter(Path);
    for i := SpinEdit1.Value to SpinEdit2.Value do
    begin
        FileName := IntToStr(i) + '.txt';
        if FileExists(Path + FileName) then
            Mess.Add(FileName + ' уже существует')
        else
        begin
            FileHandle := FileCreate(Path + FileName);
            if FileHandle < 0 then
                Mess.Add(FileName + ' невозможно создать')
            else
            begin
                FileClose(FileHandle);
                Mess.Add(FileName + ' создан')
            end
        end
    end;
    MessageBox(0, PChar(Mess.Text), 'Работа завершена', MB_ICONASTERISK);
    Mess.Free
end;

end.

очень просто:
делаешь переменную, которая изменяется от от spinedit1 до spinedit2