Ассемблер рекурсивная процедура. вычисление факториала, в чем проблемма программы? в отладчике она зацикливается.

Здесь целый букет причин зацикливания.
Стек очень быстро заканчивается, потому что параметр передаётся неправильно. Неправильно он передаётся, потому что вводимая строка вообще никак не обрабатывается. cx при входе в рекурсию просто теряется.
Не восстанавливается указатель стека в главном теле программы.
И комментарии у вас просто шикарные: "Это круг, он круглый. Это прямая линия, она прямая".

Исправленная программа. Допускается ввод чисел от 0 до 8. На любые другие символы реагирует выдачей сообщения об ошибке. Для чисел 0 ...8 выводит на экран значение факториала.

s_s segment stack
  dw 256 dup (?)
s_s ends

d_s segment
  fact1 db 2, 3 dup (?)
  res1 dw ?
  ErrMsg db 13, 10, "Ошибка! ", 13, 10, 36
d_s ends

c_s segment
    assume ss:s_s, ds:d_s, cs:c_s
begin:
    mov ax, d_s
    mov ds, ax
   
Repeat:
    mov dx, offset fact1
    mov ah, 0Ah
    int 21h
    mov al, fact1 + 1
    test al, al
    je Error
    mov al, fact1 + 2
    sub al, '0'
    cmp al, 8
    jbe NoError
Error:
    mov dx, offset ErrMsg
    mov ah, 9
    int 21h
    jmp Repeat

NoError:
    cbw
    push ax
    call factorial
    add sp, 2
    mov res1, ax
    mov al, 10
    int 29h
   
    mov ax, res1
    xor cx, cx
    mov bx, 10
Prepare:
    xor dx, dx
    div bx
    or dl, '0'
    push dx
    inc cx
    test ax, ax
    jne Prepare
Print:
    pop ax
    int 29h
    loop Print

    mov ah, 7
    int 21h
    mov ah, 4ch
    int 21h

factorial proc near
    push bp
    mov bp, sp
    mov cx, [bp + 4]
    jcxz Zero
    push cx
    dec cx
    push cx
    call factorial
    pop cx
    pop cx
    mul cx
    jmp end_proc
Zero:
    mov ax, 1
end_proc:
    pop bp
    ret
factorial endp

c_s ends
    end begin

не стал глубоко капать, но не верно обрабатываете строку которую ввели с экрана

> Ассемблер.
> ответы мэил ру.
Может тебе лучше в cyberforum.ru зайти?)