Сначала проводник кидается на "FORTAN", что является названием языка программирования, затем на END в самом конце программы
CONST Pi=3.14159265;
VAR N,P,Z,S:REAL;
I:integer;
FUNCTION F(X:REAL):REAL; (* ПОДЫНТЕГРАЛЬНАЯ ФУНКЦИЯ *)
BEGIN
F:=COS(P*X-Z*SIN(X))
END;
FUNCTION RAN(VAR I,J:INTEGER):REAL;FORTAN;(* ДАТЧИК *)
FUNCTION SIGN(VAR X,Y:REAL):REAL;FORTAN(*ЗНАКОВАЯ ФУНКЦИЯ*)
PROCEDURE MK(K:INTEGER; N,A,B:REAL;FUNCTION F:REAL; VAR S:REAL);
VAR H,R,Y,U:REAL; I,J:INTEGER; (* МЕТОД МОНТЕ-КАРЛО *)
BEGIN
H:=B-A;
S:=0.0;
R:=1;
U:=l;
I:=0;
J:=0;
U:=1.0;
IF K=1 THEN (* ВАРИАНТ 1 *)
REPEAT S:=S+F(A+RAN(I,J)*H);
R:=R+1.0
UNTIL R>N
ELSE (* ВАРИАНТ 2 *)
REPEAT Y:=F(A+RAN(I,J)*H);
IF RAN(I,J)N;
S:=H*S/N
END;
BEGIN
WRITE('BAPИAHT?');
READLN(I);
WRITE('N,P,Z?');
READLN(N,P,Z);
MK(I,N,0,РI,F,S);
WRITELN('S=',S/PI);
END.
В таком виде программа компилируется и даже что-то считает.
uses
System.SysUtils, Math;
type MyFunc = function(X: Real): Real; // объявляем процедурный тип
var
N, P, Z, S : Real;
I : Integer;
function F(X: REAL): Real;
begin
F := Cos(P*X-Z*Sin(X));
end;
function RAN(VAR I, J: INTEGER): Real;
begin
Ran := Random;
end;
// возвращает значение Х со знаком Y
function SGN(VAR X, Y: Real): Real;
begin
Sgn := Abs(X) * Sign(Y);
end;
procedure MK(K: Integer; N, A, B: Real; F: MyFunc; VAR S: Real);
var
H, R, Y, U : Real;
I, J : Integer;
begin
Randomize; // инициализация генератора случайных чисел
H := B - A; S := 0.0; R := 1.0; U := 1.0; I := 0; J := 0;
if K = 1 then (* ВАРИАНТ 1 *)
repeat
S := S + F(A + RAN(I,J) * H); R := R + 1.0;
until R > N
else (* ВАРИАНТ 2 *)
repeat
Y := F(A + RAN(I,J) * H);
if RAN(I, J) < Abs(Y) then S := S + Sgn(U, Y); R := R + 1.0;
until R > N;
S := H * S / N;
end;
begin
Write('BAPИAHT?');
Readln(I);
Write('N, P, Z ?');
Readln(N, P, Z);
MK(I, N, 0, pi, F, S);
Writeln('S = ', S / pi);
ReadLn;
end.
Несколько замечаний. Функция фортрана SIGN несколько отличается от аналогичной в паскале. Поэтому пришлось ее переименовать и привести функционал в соответствии с первоисточником. Не понятно назначение двух параметров функции RAN. Справочник говорит, что это генератор случайных чисел и с одним параметром. Поскольку ее параметры нулевые и не модифицируются, я допустил, что возможен вызов генератора псевдослучайных чисел, генерирующего результат в диапазоне [0,1). Хорошо бы проверить программу на контрольном примере.
Функции Ran, Sign, не имеют ничего кроме заголовка.
Здесь подключаются какие-то фортрановские библиотеки, откуда берутся должно быть указано в методичке.
Очевидно эти строки надо просто убрать и в uses добавить те паскалевские библиотеки, в которых эти функции есть. Только хотелось бы знать, что эти функции делают.
Например Sign, находящаяся в библиотеке math, возвращает знак числа, вроде бы подходит, "знаковая функция", но там это функция одной переменной, а здесь их две.
