Алгоритм на Pascal

Ты меняешь значение t каждый раз, а нужно прибавлять к текущему t следующий член ряда. Вот программа. Корректно работает до аргумента примерно 25, потом накапливается ошибка, вероятно, из-за больших значений степеней и факториалов. Ну с учетом периода синуса 2пи можно работать в этих пределах.
var
x1, x, y, xt, eps: real; {заданное значение аргумента, его модуль для вычислений,
вычисленное значение функции Y, текущий член ряда xt и заданная точность вычисления eps}
n, z, k: integer;

BEGIN
write('Введите X и точность вычисления: '); readln(x1, eps);
x:=abs(x1); {берем модуль аргумента, чтобы не путаться со знаками}
y:=x; {присваиваем функции значение первого члена ряда}
xt:=-x*x*x/6; {вычисляем второй член ряда}
y:=y+xt; {вычисляем значение функции}
z:=1; {z определяет знак следующего члена ряда}
n:=5; {показатель степени и факториал следующего члена ряда}
k:=2; {счетчик итераций, два члена уже найдено}
while abs(xt)>eps do {вычисляем фукцию, пока следующий член не станет меньше заданной точности}
begin
xt:=z*abs(xt)*x*x/(n-1)/n; {находим следующий член ряда}
y:=y+xt; {вычисляем значение функции}
z:=z*(-1); {меняем знак для следующего члена}
n:=n+2; {увеличиваем на 2 показатель степени и факториал для следующего члена}
inc(k);
end;
if x1<0 then y:=y*(-1); {если аргумент был отрицательным - меняем у функции знак (синус нечетная функция) }
writeln('Вычисленное значение sin(x)= ',y, ' за ',k,' итераций'); {результат}
writeln('Контрольное значение: ',sin(x1))
END.
==========================================
Введите X и точность вычисления: 0.3 0.0001
Вычисленное значение sin(x)= 0.29552025 за 3 итераций
Контрольное значение: 0.29552020666134

var x: real;
function sinus(x: real): real;
var y, p, s, q: real; begin
y := - x * x; p := x; sinus := x;
q := 1; while abs(p) > 1e-4 do begin
q := q + 2; p := p * y / (q * (q - 1));
sinus := sinus + p end;
writeln(trunc((q + 1) / 2),
' terms of the series') end;
begin writeln(sinus(0.3)) end.